<%
'Natterchat version 1.12 configuration file

'Leave the line below alone. For error reporting, comment it out.
On Error Resume Next
Dim strDBType, strAccessLoc, strConnString
'#############################
'## CONFIGURATION SETTINGS  ##
'#############################

'choose your database type

'strDBType = "sqlserver"
strDBType = "access"
'strDBType = "mysql"

'If you are using access you need to set this line the the actual file path to your access database
'strAccessLoc = "C:\absolute\path\to\natterchat112.mdb"

'Choose your connection to the database
strConnString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("natterchat112.mdb") '## MS Access 2000 using virtual path
'strConnString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("/USERNAME/db/natterchat112.mdb") '## MS Access 2000 on Brinkster
'strConnString = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strAccessLoc '## MS Access 2000
'strConnString = "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("natterchat112.mdb") '## MS Access 97 using virtual path
'strConnString = "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & Server.MapPath("/USERNAME/db/natterchat112.mdb") '## MS Access 97 on Brinkster
'strConnString = "DRIVER={Microsoft Access Driver (*.mdb)}; DBQ=" & strAccessLoc '## MS Access 97
'strConnString = "Provider=SQLOLEDB;Data Source=SERVER_NAME;database=DB_NAME;uid=UID;pwd=PWD;" '## MS SQL Server 6.x/7.x/2000 (OLEDB connection)
'strConnString = "driver={SQL Server};server=SERVER_NAME;uid=UID;pwd=PWD;database=DB_NAME" '## MS SQL Server 6.x/7.x/2000 (ODBC connection)
'strConnString = "driver=MySQL;server=SERVER_IP;uid=UID;pwd=PWD;database=DB_NAME" '## MySQL
'strConnString = "natterchatgdndsn1" '## DSN

'#################################################################################
'##                       DONT EDIT ANYTHING PAST HERE                          ##
'#################################################################################

'Version and Creation Date
Dim strVersion : strVersion = "Natterchat Version 1.12 Build 15 Final Release. Created 17 September 2004"

if strConnString = "" OR strDBType = "" then
	Response.Redirect("setup.asp?Error=parameters")
end if

'Declare database connection variables
Dim conn, rs, varSQL

'find setup data
varSQL = "SELECT * FROM SETUP WHERE SETUPID = 1;"
Set rs=Server.CreateObject("ADODB.recordset")
rs.Open varSQL, strConnString, 0, 1
If rs.EOF Then
	Session.Contents("strConnString") = strConnString
	Response.Redirect("setup.asp?Error=setup")
Else
	Application("IdleTime") = rs("IDLETIME")
	Application("KickOutTime") = rs("KICKOUTTIME")
	Application("UserControlScroll") = rs("USERCONTROLSCROLL")
	
	If Session.Contents("MessageScroll") = "" OR isNull(Session.Contents("MessageScroll")) OR Session.Contents("MessageScrollUser") = False OR Application("UserControlScroll") = False Then
		Session.Contents("MessageScroll") = rs("MESSAGESCROLL")
		Application("MessageScroll") = Session.Contents("MessageScroll")
	End If
	
	Application("MessageNumber") = rs("MESSAGENUMBER")
	Application("AllowEmoticons") = rs("ALLOWEMOTICONS")
	Application("MsgRefreshDelay") = rs("MESSAGEREFRESHDELAY")
	Application("UsrRefreshDelay") = rs("USERREFRESHDELAY")
	Application("DefLang") = rs("LANGUAGE")
	Application("ChatName") = rs("CHATNAME")
	Application("ChatImage") = rs("CHATIMAGE")
	Application("ChatEmail") = rs("EMAILADDRESS")
	Application("HousecleanDelUsers") = rs("HOUSECLEANDELUSERS")
	Application("HousecleanDelRooms") = rs("HOUSECLEANDELROOMS")
	Application("HousecleanDelMessages") = rs("HOUSECLEANDELMESSAGES")
	Application("HousecleanDelMessagesAfter") = rs("HOUSECLEANDELMESSAGESAFTER")
End If
rs.Close
Set rs = Nothing

'check to see if there were any database access errors
If Err.Number<>0 Then
	Response.Redirect("setup.asp?Error=database")
End If

'Choose the language file to run here
varSQL = "SELECT FILENAME FROM LANGUAGES WHERE LANGUAGEID = " & Application("DefLang") & ";"
Set rs=Server.CreateObject("ADODB.recordset")
rs.Open varSQL, strConnString
rs.MoveFirst
	Dim varDefLangFile	: varDefLangFile = rs("FILENAME")
rs.Close
Set rs = Nothing
'if everything is set correctly in this page and this is run for the first time the above call with fail and go to the setup page
If Err.Number<>0 Then
	Session.Contents("strConnString") = strConnString
	Response.Redirect("setup.asp?Error=setup")
End If

If isNull(session.contents("Language")) OR session.contents("Language") = "" Then
	Session.Contents("Language") = varDefLangFile
End If

Server.Execute(Session.Contents("Language"))

'Response.Write Application("content_header")
%>
<%
Response.Expires = 0
server.Execute("inc_houseclean.asp")
%>
<html>
<head>
<title><%=application("lang_home_title")%></title>
<link href="styles.css" rel="stylesheet" type="text/css" />
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1"></head>
<body bgcolor="#000066">
<p>
<%
Response.Write 	"<font size=""3"">" & application("lang_home_1") & "</font></p>" & _
				"<p><strong>" & application("lang_home_2") & "</strong></p>" & _
				"<p>" & application("lang_home_3") & "</p>" & _
				"<p>" & application("lang_home_4") & "</p>"

Dim varError : varError = request("Error")
If varError = "Registered" Then
	Response.Write 	"<p><font color=""red""><strong>! ! " & application("lang_home_5") & " ! !</strong></font></p>"
ElseIf varError = "badcomb" Then
	Response.Write 	"<p><font color=""red""><strong>! ! " & application("lang_home_6") & " ! !</strong></font></p>"
ElseIf varError = "passsent" Then
	Response.Write "<p><font color=""red""><strong>" & application("lang_home_7") & ".</strong></font></p>"
End If

'List the rooms in the database and the number users in each room
Dim arrRooms(), varRooms, numberrooms, varRoomID, arrayR, i, F, varNoUsers, varName
i = 0
varSQL = "SELECT ROOMID FROM ROOMS;"
Set rs=Server.CreateObject("ADODB.recordset")
rs.Open varSQL, strConnString, 0, 1
If rs.EOF Then
	varRooms = "<option value='0'>There are no rooms</option>"
Else
	rs.MoveFirst
	numberrooms = 0
	Do
		'read the IDs into a dynamic array
		varRoomID = rs("ROOMID")
		arrayR = "yes" 'this tells us that there are entries in the array.
		ReDim Preserve arrRooms(i)
		arrRooms(i) = varRoomID
		i = i + 1
		numberrooms = numberrooms + 1
		rs.MoveNext
	Loop Until rs.EOF
End If
rs.Close
Set rs = Nothing

'Now we need to get the number of users in each of the rooms
If arrayR = "yes" Then
	For F = LBound(arrRooms) To UBound(arrRooms)
		'Get a count of the active users in the current room from each round of the array
		varSQL = "SELECT Count(UserID) AS NoUsers FROM USERS WHERE ROOMID = " & arrRooms(F) & ";"
		Set rs=Server.CreateObject("ADODB.recordset")
		rs.Open varSQL, strConnString
		varNoUsers = rs("NoUsers")
		rs.Close
		Set rs = Nothing
		'Get the room name
		varSQL = "SELECT * FROM ROOMS WHERE ROOMID = " & arrRooms(F) & ";"
		Set rs=Server.CreateObject("ADODB.recordset")
		rs.Open varSQL, strConnString
		varName = rs("NAME")
		rs.Close
		Set rs = Nothing
		'output these in the <option> tag for the home page.
		If F = 0 Then
			varRooms = varRooms & "<option value='" & arrRooms(F) & "' selected>" & varName & " (" & varNoUsers & ")</option>"
		Else
			varRooms = varRooms & "<option value='" & arrRooms(F) & "'>" & varName & " (" & varNoUsers & ")</option>"
		End If	
	Next
End If
Response.Write 	"</p>" & _
				"<form name=""frmLogin"" action=""login.asp"" method=""post"">" & _
				"<table border=""0"" cellpadding=""0"">" & _
				"<tr>" & _
				"<td width=""90""><strong>" & application("lang_home_8") & "</strong></td><td><input type=""text"" name=""txtUsername"" class=""input"" accesskey=""u"" /></td>" & _
				"</tr><tr>" & _
				"<td><strong>" & application("lang_home_9") & "</strong></td><td><input type=""password"" name=""txtPassword"" class=""input"" accesskey=""s"" /> <a href=""register_passremind.asp"">" & application("lang_home_10") & "</a></td>" & _
				"</tr><tr>" & _
				"<td valign=""top""><strong>" & application("lang_home_11") & "</strong></td><td><select name=""sltRoom"" size=" & numberrooms & " class=""input"" accesskey=""r"">" & _
				varRooms & "</select></td>" & _
				"</tr><tr>"
				If application("AllowEmoticons") = True Then
					Response.Write "<td><strong><u>E</u>moticons: </strong></td><td><input type=""checkbox"" name=""chkEmoticons"" accesskey=""e"" value=""true"" checked /> (" & application("lang_home_12") & ")</td>" & _
					"</tr><tr>"
				End If
				Response.Write "<td></td>" & _
				"<td><input type=""submit"" name=""submit"" value='" & application("lang_home_13") & "' class=""inputbtn"" /></td>" & _
				"</tr><tr>" & _
				"<td colspan=""2"">" & application("lang_home_14") & ".</td>" & _
				"</tr></table>" & _
				"</form>"
				
				Dim varLangID, varLangName, varLangFile, varFileLoc, ChangeLang, LangList
				varSQL = "SELECT * FROM LANGUAGES"
				Set rs=Server.CreateObject("ADODB.recordset")
				rs.Open varSQL, strConnString
				If NOT rs.EOF Then
					rs.MoveFirst
					Do
						varLangID = rs("LANGUAGEID")
						varLangName = rs("LANGUAGENAME")
						varLangFile = rs("FILENAME")
						varFileLoc = rs("FLAGFILELOC")
						If NOT varLangFile = session.contents("Language") Then
							ChangeLang = "<p>" & application("lang_home_15") & "<br />"
							LangList = LangList & " <a href='preferences_langchange.asp?ID=" & varLangID & "'><img src='" & varFileLoc & "' alt='" & varLangName & "' width='33' height='22' /></a>"
						End If
						rs.MoveNext
					Loop Until rs.EOF
					response.write ChangeLang & LangList
				End If
				rs.Close
				Set rs = Nothing
				
				Response.Write "<p align=""center""><font color=""red""><em>" & application("lang_home_16") & " <a href=""http://www.natterchat.co.uk"">Natterchat v1.12</a></em></font></p>"
%>
</body>
</html>